Fundamental Mathematics from an Advanced Standpoint

Math 4303

Helmut Knaust, Department of Mathematical Sciences, UTEP, El Paso TX 79968
hknaust@utep.edu

Last Edits: 3/10/2011

The Riemann Sphere Model of the Complex Numbers

Manipulate[Graphics3D[{AbsolutePointSize[8],Point[{x,y,0}],Point[{0,0,1}],
Point[{(1/((x^2)+(y^2)+1)) x,(1/((x^2)+(y^2)+1))  y,1-(1/((x^2)+(y^2)+1))} ],{Thick,Line[{{0,0,1},{x,y,0}}]},{Opacity[.8],Sphere[{0,0,1/2},1/2]}},FaceGrids->{{0,0,-1}},FaceGridsStyle->Directive[Red,Thin],Axes->True,AxesLabel->{"x","y","z"},BoxRatios->{4,4,1},ImageSize->600,BaseStyle->{14,Bold},PlotRange->{{-2.1,2.1},{-2.1,2.1},{0,1}}],{x,-2,2},{y,-2,2}]

A circle (blue) in the Complex Plane correspond to a circle (red) on the Riemann Sphere.

sp[{x_,y_}]:={x,y,x^2+y^2}/(1+x^2+y^2)
p1=ParametricPlot3D[sp[{1.75Cos[t]+1,1.75Sin[t]-1}],{t,0,2π},PlotStyle->Red];
p2=ParametricPlot3D[{1.75Cos[t]+1,1.75Sin[t]-1,0},{t,0,2π},PlotStyle->Blue];Animate[{x,y}={1.75Cos[t]+1,1.75Sin[t]-1};Show[Graphics3D[{{Opacity[0.7],Sphere[{0,0,.5},.5]},{Line[{{x, y,0},{0,0,1}}]},{AbsolutePointSize[8],Point[{0,0,1}],{Blue,Point[{x,y,0}]},{Red,Point[sp[{x,y}]]}}},ImageSize->600,PlotRange->{{-1,3},{-3,1},{0,1}}],p1,p2],{t,0,2π}]

A line (blue) in the Complex Plane corresponds to  a circle (red) “though” the north pole on the Riemann Sphere.

sp[{x_,y_}]:={x,y,x^2+y^2}/(1+x^2+y^2)
p1=ParametricPlot3D[sp[{t+1,t-1}],{t,-10,10},PlotStyle->Red];
p2=ParametricPlot3D[{t+1,t-1,0},{t,-2,2},PlotStyle->Blue];Animate[{x,y}={t+1,t-1};Show[Graphics3D[{{Opacity[0.5],Sphere[{0,0,.5},.5]},{Line[{{x, y,0},{0,0,1}}]},{AbsolutePointSize[8],Point[{0,0,1}],{Blue,Point[{x,y,0}]},{Red,Point[sp[{x,y}]]}}},ImageSize->600,PlotRange->{{-2,3},{-3,1},{0,1}}],p1,p2],{t,-2,2},AnimationDirection->ForwardBackward]