Cannon Balls and Javelins

Helmut Knaust, Department of Mathematical Sciences, UTEP, El Paso TX 79968
hknaust@utep.edu
3/3/2012

Projectile Motion

The initial velocity vector results in a horizontal and vertical component:

Graphics[{Arrow[{{0,0},{4,3}}],Arrow[{{0,0},{4,0}}],Arrow[{{0,0},{0,3}}],{Dotted,Line[{{0,3},{4,3},{4,0}}]},Text["(v0 cos(θ), v0 sin(θ))",{2,1.5},{-1,2}],Text["v0 cos(θ)",{1.5,0},{-2,2}],Text["v0 sin(θ)",{0,1.5},{-1.5,0}],Circle[{0,0},1,{0,ArcTan[3/4]}],Text["θ",{.65,.25},{-1.5,0}]},BaseStyle->{Bold,12}]
Clear[v0,y0,θ,g]

Horizontal and vertical motion are independent.
t is time (in sec.), v0 is the norm of the velocity vector (m/sec), y0 is the release height (m), θ is the release angle, and g is the gravitational constant (9.81 m/(sec^2)).

x[t_,θ_]:=v0 Cos[θ]t 
y[t_,θ_]:=y0+v0 Sin[θ] t-g/2 t^2

When does the projectile hit the ground?

sol=FullSimplify[Solve[y[t,θ]==0,t]][[2]]

What is the horizontal distance traveled when the projectile hits the ground?

FullSimplify[xmax[θ_]=x[t,θ]/.sol]

Let' s specify some of the parameters:

v0=30;y0=2;g=9.81;

Below are the flight paths for various release angles:

Manipulate[ParametricPlot[{x[t,θ],Max[{y[t,θ],0}]},{t,0,10},PlotRange->{{0,120},{0,60}},AspectRatio->Automatic],{θ,0,π/2,π/180}]

The optimal release angle (in degrees):

opt=Solve[xmax'[θ]==0,θ][[1,1,2]]/Degree

Distance traveled with respect to release angle:

Plot[xmax[θ],{θ,0,π/2},Ticks->{Table[{π k /36,ToString[5  k]<>"°"},{k,0,18}],Automatic},Epilog->{Dotted,Blue,Line[{{opt Degree,0},{opt Degree,xmax[opt Degree]}}]}]

Javelin

For javelin throwers, the magnitude of the initial velocity depends on the release angle:

Clear[v0];h0=2;g=9.81;

v0[θ_]:=28.5-.13θ /Degree;
Plot[v0[θ],{θ,π/8,π/3},Ticks->{Table[{π k /36,ToString[5  k]<>"°"},{k,0,18}],Automatic}]

x[t_,θ_]:= v0[θ] Cos[θ]t 
y[t_,θ_]:=h0+v0[θ] Sin[θ] t-g/2 t^2

Manipulate[ParametricPlot[{x[t,θ],Max[{y[t,θ],0}]},{t,0,10},PlotRange->{{0,70},{0,30}}],{θ,0,π/2,π/180}]

When does the javelin hit the ground?

sol=Solve[y[t,θ]==0,t][[2]]

The optimal release angle (in degrees):

xmax[θ_]=x[t,θ]/.sol;
opt=FindRoot[xmax'[θ],{θ,π/4}][[1,2]]/Degree

Distance with respect to relase angle:

Plot[xmax[θ],{θ,0,π/2},Ticks->{Table[{π k /36,ToString[5  k]<>"°"},{k,0,18}],Automatic},Epilog->{Dotted,Line[{{opt Degree,0},{opt Degree, xmax[opt Degree]}}]}]

References

Viitasalo, J.T., Korjus, T., 1988. On-line measurement of kinematic
characteristics for javelin. In : deGroot, G., et al. (Ed.), Biomechanics
XI-B. Free University Press, Amsterdam, pp.582–587.

http://www.speerschule.ch/docs/doc_wjc09-biomech2.pdf