Differential Equations: Problem 5.1.22

Helmut Knaust, Department of Mathematical Sciences, UTEP, El Paso TX 79968, hknaust@utep.edu
4/28/2016; last edits 4/29/2016

Analyze the equilibrium point behavior of the following one-parameter family of non-linear differential equations:
	x'=y-(x^2)
	y'=y-x-a

Finding the equilibrium points

sol=Solve[{y-x^2==0,y-x-a==0},{x,y}]

Here are the two equilbrium points:

eq1=sol[[1,All,2]]

eq2=sol[[2,All,2]]

Note that they are real only when a≥-(1/4).

Finding the eigenvalues

J={{-2x,1},{-1,1}}

Eigenvalues at the first equilibrium point:

f1[a_]=Eigenvalues[J]/.{x->eq1[[1]]}

Where is their discrimant equal to 0?

Solve[(((1-(Sqrt[4 a+1])))^2)+2 (1-(Sqrt[4 a+1]))-3==0]

A plot of their imaginary parts:

Plot[Im[f1[a]],{a,-1/4,10},PlotStyle->{Red,Thick},AxesLabel->{"a",None}]

Thus the eigenvalues are complex for -1/4<a<(15/4) and real for a>(15/4)

Below is a plot of the real part of the eigenvalues:

Plot[Re[f1[a]],{a,-1/4,10},PlotStyle->{Blue,Thick},AxesLabel->{"a",None}]

... and the plot of the two eigenvalues when they are real:

Plot[{f1[a][[1]],f1[a][[2]]},{a,15/4,10},PlotStyle->{Orange,Purple},AxesOrigin->{15/4,0},AxesLabel->{"a",None}]

Thus the first equilibrium point is a spiral source for -1/4<a<(15/4) and a source for a>(15/4).

Eigenvalues at the second equilibrium point:

Let' s repeat for the second equilibrium point:

f2[a_]=Eigenvalues[J]/.{x->eq2[[1]]}

Plot[Im[f2[a]],{a,-1/4,10},PlotStyle->{Red,Thick},AxesLabel->{"a",None}]

Thus the eigenvalues are always real. Below is their plot:

Plot[{f2[a][[1]],f2[a][[2]]},{a,-1/4,10},PlotStyle->{Orange,Purple},AxesOrigin->{0,0},AxesLabel->{"a",None}]

One of the eigenvalues is positive, the other one is negative, so the second equilibrium point is a saddle for a>-(1/4).