Shannon Wavelet

Helmut Knaust, Department of Mathematical Sciences, UTEP, El Paso TX 79968
hknaust@utep.edu
10/13/2010; last edit 10/29/2015

SetDirectory[NotebookDirectory[]];
<< "DW.m"

s[x_]=Sin[π x]/(π  x)

Plot[s[x],{x,-6,6},PlotRange->All,Ticks->{Table[n,{n,-6,6}],Automatic},PlotStyle->{Thick,Blue}]

Checking the orthogonality of translates:

Integrate[s[2x] s[2x-1],{x,-Infinity,Infinity}]

Checking orthonormality:

Integrate[(s[x])^2,{x,-Infinity,Infinity}]

Finding the coefficients for the dilation equation:

n=5;Table[Integrate[s[x] Sqrt[2]s[2x-k],{x,-Infinity,Infinity}],{k,-n,n,1}]

A table of the large dilation coefficients:

n=9;tab=Table[Sqrt[2](-1)^((j-1)/2)(1-(-1)^j)/(2j π),{j,-n,n}]/.Indeterminate->1/Sqrt[2]
N[tab]

Plotting the Shannon father wavelet and its dilation approximation:

tab.Table[Sqrt[2]s[2x-j],{j,-n,n}]

Plot[{s[x],tab.Table[Sqrt[2]s[2x-j],{j,-n,n}]},{x,-6,6},PlotStyle->{{Thick,Blue},{Thick,Red}},PlotRange->All,Ticks->{Table[n,{n,-6,6}],Automatic}]

c[0]=1/2;
c[k_]=Which[Mod[k,4]==1,1/(k π),Mod[k,4]==3,-1/(k π),Mod[k,2]==0,0]

coeff=Table[c[k],{k,-50,50}];

FourierFilterPlot[coeff]

The wavelet :

coeff2=Table[(-1)^k c[k],{k,50,-50,-1}]

FourierFilterPlot[coeff2]

Plot[Sqrt[2]coeff2.Table[s[2x-k],{k,50,-50,-1}],{x,-5,5},PlotStyle->{Thick,Red},PlotRange->All]